批量搜索并复制/剪切文件的批处理程序

发表时间 ·

搜索包含关键字的文件名是最常用的功能之一,比如按人名搜索mp3、按内容搜索图纸等等,当需要搜索成百上千个关键词时,会消耗大量的人力和时间,这时就需要批量搜索功能。本文介绍一个我自己编写的、用于批量搜索文件的批处理程序。

搜索包含关键字的文件名是最常用的功能之一,比如按人名搜索mp3、按内容搜索图纸等等,当需要搜索成百上千个关键词时,会消耗大量的人力和时间,这时就需要批量搜索功能。

传统方法

Windows XP自带了批量搜索的功能,在按(Win+F)弹出的搜索框中,填入若干关键词,用逗号隔开,这样搜出的结果是包含至少一个关键词的文件。但是这种搜索方法有关键字数量的限制,而且要把一堆关键词用逗号隔开也是需要点工夫的,当然你可以用Excel处理,但总归比较麻烦。下面介绍一个我自己编写的批处理程序。

任务描述

所谓批量搜索是在一批文件名里寻找多个关键词,比如

关键词列表:AA,BB,CC
目标文件名:AA1,BB2,DD3,BBC1,EE2,Abb

批量搜索得到的结果有:AA1,BB2,BBC1,Abb
因为Windows系统对文件名的大小写只记录,不区分,所以Abb也能被搜出来。

解决方法

利用批处理程序中强大的for命令,可以很好的完成批量的搜索。结合其他批处理命令,还能将搜出来的文件复制或者剪切到目的路径下面。

首先把关键字保存在名叫“list.txt”的文本文件里,每个关键字占一行。注意不能有空格、空行、空回车。例如:

AA
BB
CC

然后把下面的代码保存成以 *.bat 为扩展名的批处理文件。代码如下:

::Batch search & copy/move,  Mar 21,2009
::..

@echo off
color 3E
echo 本程序复制/剪切当前目录下含有特定关键字的特定类型文件
echo 注意:覆盖不提示,请小心操作
echo 注意:关键字列表不要有空格、空行、空回车
echo.
if not exist list.txt (echo.
echo 请先将关键字列表保存为list.txt...
pause > NUL
exit
)
echo.
echo 选择要进行的操作:
set /p opt=复制(c) or 剪切(x):
if %opt% NEQ c if %opt% NEQ x (
echo 没有选项,byebye!
pause >NUL
exit
)
set /p ext=指定文件扩展名(不含".",比如pdf,不指定请输入*):
set /p url=目标文件夹路径(不可在当前目录内):
if not exist %url% md %url%
if %opt%==c set task=复制
if %opt%==x set task=剪切
echo 按任意键开始%task%....
pause > NUL

set count=0
for /f "tokens=*" %%i in (list.txt) do (
  for /r %%j in (*%%i*.%ext%) do (
echo 正在%task% %%j 到 %url%
if %opt%==c (copy "%%j" %url% >NUL)
if %opt%==x (move "%%j" %url% >NUL)
set /a count+=1
 )
)
echo.
echo 任务完成!共%task%了%count%个文件
echo.
echo by www.lfhacks.com
echo ..
pause >NUL
exit

把批处理文件和list.txt都放在要搜索的文件目录下,运行批处理文件,按提示操作即可,注意大小写敏感。由于for命令先天的限制,有两点需要注意:

  1. 被搜索文件不能放在根目录下,需要放在子目录内
  2. 复制或者剪切的目的地最好在另外一个驱动器内,不然可能会造成死循环。

对上述代码稍作修改,可以得到其他定制的功能,比如,下面的代码就是建立以关键字命名的独立目录,作为复制/剪切的目的地。这个代码可以用来将文件按某个字段分配到多个文件夹里:

::Batch search & copy/move,  Mar 21,2009
::..

@echo off
color 3E
echo 本程序复制/剪切当前目录下含有特定关键字的特定类型文件
echo 注意:覆盖不提示,请小心操作
echo 注意:关键字列表不要有空格、空行、空回车
echo.
if not exist list.txt (echo.
echo 请先将关键字列表保存为list.txt...
pause > NUL
exit
)
echo.
echo 选择要进行的操作:
set /p opt=复制(c) or 剪切(x):
if %opt% NEQ c if %opt% NEQ x (
echo 没有选项,byebye!
pause >NUL
exit
)
set /p ext=指定文件扩展名(不含".",比如pdf,不指定请输入*):
set /p url=目标文件夹路径(不可在当前目录内,末尾不要带斜杠\):
if not exist %url% md %url%
if %opt%==c set task=复制
if %opt%==x set task=剪切
echo 按任意键开始%task%....
pause > NUL

set count=0
for /f "tokens=*" %%i in (list.txt) do (
  md %url%\%%i
  for /r %%j in (*%%i*.%ext%) do (
echo 正在%task% %%j 到 %url%\%%i
if %opt%==c (copy /Y "%%j" "%url%\%%i" >NUL)
if %opt%==x (move /Y "%%j" "%url%\%%i" >NUL)
set /a count+=1
 )
)
echo.
echo 任务完成!共%task%了%count%个文件
echo.
echo by www.lfhacks.com
echo ..
pause >NUL
exit

在批量搜索并转移文件后,往往需要和原有的关键字比对,知道搜索到了多少文件。这就需要一个工具,能够批量检测一批关键字是否存在于一堆文件里。请参考我的另一篇文章: 《批量检测文件(夹)是否存在的批处理程序》

批处理的for命令还有很多强大的功能,如果你开发了其他的用途,欢迎和我交流:)


相关文章   欢迎到 留言板 写下你的看法。
  本页面内容采用 署名协议 CC-BY 授权。欢迎转载,请保留原文链接